Wikidata Enpoint SparQL et les peintures de Goya

En février 2015, le billet Wikidata Query et les peintures de Goya présentait la manière de requêter les données œuvres d’art de Wikidata avec l’API Wikidata Query. Depuis une autre technologie de requête, conforme aux standards du web sémantique (avec quelques ajouts spécifique à Wikidata), a été mise en place : l’Endpoint SparQL de Wikidata.

Afin de faciliter l’utilisation de cet outil, Ash Crow a fait un excellent tutoriel : Mais combien y a-t-il de femmes scientifiques sur Wikipédia ? (this time with SPARQL). À notre tour de montrer comment on peut utiliser cet Endpoint, et une fois encore dans le domaine des œuvres d’art.

L’objectif est comme précédemment de retrouver toutes les peintures de Francisco de Goya sur Wikidata.

LLes peintures de Goya sur Crotos
Les peintures de Goya sur Crotos
(réutilisant les données de Wikidata et les images de Wikimedia Commons)


Les peintures

Tout d’abord nous recherchons les éléments (?item) ayant pour nature (wdt:P31) peinture (Q3305213) ou une sous-classe (aquarelle, peinture murale…, propriété P279) :

PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
SELECT distinct ?item where {
    ?item wdt:P31/wdt:P279* wd:Q3305213 .
}
LIMIT 10


Requête. Résultat total au 18/10/2015 : 107 940 items « peinture ».


Les peintures avec leur titre

La requête précédente nous a permis de retrouver tous les éléments peinture sur Wikidata avec leur numéro d’identifiant (Q plus des chiffres). Si l’on souhaite récupérer le titre associé à ces peintures (en français d’abord, sinon en espagnol ou en anglais), il convient d’ajouter dans notre requête le service ad hoc wikibase qui permet de récupérer le libellé vedette des éléments :

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
select distinct ?item ?itemLabel
where {
    ?item wdt:P31/wdt:P279* wd:Q3305213 .
    SERVICE wikibase:label {
       bd:serviceParam wikibase:language "fr,es,en" .
    }
}
LIMIT 10


Résultat avec les libellés


Les peintures crées par Goya

À la requête précédente sur les peintures il suffit d’ajouter en critère de sélections les items créés par (propriété p170) Francisco de Goya (Q5432):

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
select distinct ?item ?itemLabel
where {
    ?item wdt:P31/wdt:P279* wd:Q3305213 .
    ?item wdt:P170 wd:Q5432 .
    SERVICE wikibase:label {
        bd:serviceParam wikibase:language "fr,es,en" .
    }
}


Résultat


Les peintures crées par Goya avec image

Dernière étape, on ajoute en critère optionnel la propriété image (p18) pour récupérer le nom d’un éventuel fichier image sur Wikimedia Commons :

PREFIX bd: <http://www.bigdata.com/rdf#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
select distinct ?item ?itemLabel ?img
where {
    ?item wdt:P31/wdt:P279* wd:Q3305213 .
    ?item wdt:P170 wd:Q5432 .
    OPTIONAL{
    	?item wdt:P170 ?img.
    }
    SERVICE wikibase:label {
       bd:serviceParam wikibase:language "fr,es,en" .
    }
}

Et voilà le résultat attendu : peintures de Goya avec l’Endpoint SparQL de Wikidata

Ce résultat pourrait bien sûr être complété avec d’autres données disponibles dans les éléments Wikidata (date de création [propriété P571], collection [propriété P195], numéro d’inventaire [propriété P217]… cf. Structure générique d’élément œuvre d’art sur Wikidata). Les données produites par les requêtes peuvent être ensuite récupérées sous divers formats (CSV, TSV, JSON, Simple TSV, Full JSON).


Bonus ! Tout récupérer sans coder

Avec l’outil Œuvres d’art du Lab de Crotos, il est possible de créer une liste d’œuvres selon une collection ou un créateur. La liste produite est paramétrable et téléchargeable au format CSV (compatible avec Excel ou autres tableurs). Et hop :

Liste complète des œuvres de Goya sur Wikidata


L’Endpoint SparQL apparaît déjà comme une avancée notable dans les outils de requête de Wikidata.
Par ailleurs, dans le domaine des œuvres d’art, comme évoqué dans un précédent billet sur les développements de Crotos, le contenu de Wikidata a atteint un volume conséquent et toujours croissant, rassemblant et structurant des informations sur les œuvres dans une large base de données multilingue et collaborative. Si en plus toutes les données sont libres sur Wikidata (en CCO) et que nous disposons également des images libres et reliées de Wikimedia Commons, alors nous avons déjà largement de quoi récupérer, réutiliser, analyser, créer et s’émerveiller.

Doña Isabel de Porcel
Doña Isabel de Porcel, peinture de Francisco de Goya, 1805, National Gallery (NG1473), Q1585399

Enjoy!